Arma 3 - ほんとにござるか？本当に鹵獲するでござるか？

実際の兵士とかってゲリラとかでもない限り鹵獲とかしないよねぇ。というわけで鹵獲を無理やり禁止するスクリプト。
某氏のリクエストです。

本当はEvent Handlerでやりたかったんだけど、確度が低かったのでwhileループにしました。
リスポーンした時はもう一度実行してね。これをinit.sqfかどっかに入れると多分なんとかなる。マルチプレイ動作未確認。
この状態だと、Katibaを手に入れた時すぐに捨てるようになっています。引数1番目のBooleanをtrueにすると、ホワイトリスト（リスト内の武器しか使えなくなる）になります。

[
 [//リスト　中身を改変して使ってね
  "arifle_Katiba_F"
 ],
 false//falseでブラックリスト、trueでホワイトリスト
] spawn {
 params ["_list","_whitelisted"] ;
 _list = _list apply {toLower _x} ;
 while {alive player} do {
  if (!_whitelisted) then {
   {
    if ((toLower ([_x] call BIS_fnc_baseWeapon)) in _list) then {
     _wh = "GroundWeaponHolder_Scripted" createVehicle position player ;
     player action ["DropWeapon",_wh,_x] ;
    } ;
   } forEach weapons player ;
  } else {
   {
    if !((toLower ([_x] call BIS_fnc_baseWeapon)) in _list) then {
     _wh = "GroundWeaponHolder_Scripted" createVehicle position player ;
     player action ["DropWeapon",_wh,_x] ;
    } ;
   } forEach weapons player ;
  } ;
  sleep 1 ;
 } ;
} ;